# Customized Panes for 'xxxxxxxx' Created: 2008/11/04
# PANE:Invoice Balances Graph
[PANE]
Phil  xxxxxxxx    01000Customer Invoice Balances                                                                           010                                                                                                                                                                                                                                                               000000500000IMP04Z001M
[VBSCRIPT]
' This script creates a graph for Customer Ageing
' -----------------------------------------------
Option Explicit

Function CustomizedPane_OnRefresh()
   RefreshGraph()
end Function

Function CustomizedPane_OnLoad()
   dim GraphProperties
   
   GraphProperties = GraphProperties & "<CodejockChart>"
   GraphProperties = GraphProperties & "<Titles><Title Visible='1' Text='Invoice Ageing'> </Title></Titles>"
   GraphProperties = GraphProperties & "<Panels>"
   GraphProperties = GraphProperties & "<Panel>"    ' Panel 1
   GraphProperties = GraphProperties & "<AxisX><Title Text='Ageing' /></AxisX>"
   GraphProperties = GraphProperties & "<AxisY><Title Text='Value' /></AxisY>"
   GraphProperties = GraphProperties & "</Panel>"
   GraphProperties = GraphProperties & "</Panels>"
   
   GraphProperties = GraphProperties & "<Series LegendText='Value' Style='Bar' />"
   GraphProperties = GraphProperties & "</CodejockChart>"
      
   CustomizedPane.CodeObject.GraphProperties = GraphProperties

   RefreshGraph()

End Function

' This function refreshes the contents of the graph.
function RefreshGraph()

dim XMLOut, XMLParam, Customer
Customer = CustomizedPane.CodeObject.RefreshValue

if Customer = "" then
   exit function
end if

XMLParam = XMLParam & " <Query>"
XMLParam = XMLParam & "   <Key>"
XMLParam = XMLParam & "     <Customer><![CDATA[" & Customer & "]]></Customer>"
XMLParam = XMLParam & "   </Key>"
XMLParam = XMLParam & "   <Option>"
XMLParam = XMLParam & "     <IncludeFutures>N</IncludeFutures>"
XMLParam = XMLParam & "     <IncludeTransactions>N</IncludeTransactions>"
XMLParam = XMLParam & "     <IncludeCheckPayments>N</IncludeCheckPayments>"
XMLParam = XMLParam & "     <IncludePostDated>N</IncludePostDated>"
XMLParam = XMLParam & "     <IncludeZeroBalances>N</IncludeZeroBalances>"
XMLParam = XMLParam & "     <IncludeCustomForms>N</IncludeCustomForms>"
XMLParam = XMLParam & "     <IncludeInvoices>Y</IncludeInvoices>"
XMLParam = XMLParam & "     <AsOfPeriod>C</AsOfPeriod>"
XMLParam = XMLParam & "     <AgeingOption>S</AgeingOption>"
XMLParam = XMLParam & "   </Option>"
XMLParam = XMLParam & " </Query>"
on error resume next
XMLOut = CallBO("ARSQRY",XMLParam,"auto")

if err then
    exit function
end if
' Switch on error handling
on error goto 0


'Load the XmlOut into the DOM
Dim xmlDoc
Set xmlDoc = createobject("Msxml2.FreeThreadedDOMDocument")
xmlDoc.async = false
xmlDoc.LoadXML(Xmlout)

Dim CurrentBalance
Dim Days30
Dim Days60
Dim Days90

Set CurrentBalance = xmlDoc.DocumentElement.SelectSingleNode("//ARStatement/TotalSection/Current")
Set Days30 = xmlDoc.DocumentElement.SelectSingleNode("//ARStatement/TotalSection/Days30")
Set Days60 = xmlDoc.DocumentElement.SelectSingleNode("//ARStatement/TotalSection/Days60")
Set Days90 = xmlDoc.DocumentElement.SelectSingleNode("//ARStatement/TotalSection/Days90")


Dim FinalString

FinalString = FinalString & "<CodejockChart><Series><Points>"

FinalString = FinalString & "<Point Label='Current' Value='" & CurrentBalance.text & "' />"
FinalString = FinalString & "<Point Label='30 Days' Value='" & Days30.text & "' />"
FinalString = FinalString & "<Point Label='60 Days' Value='" & Days60.text & "' />"
FinalString = FinalString & "<Point Label='90 Days' Value='" & Days90.text & "' />"

FinalString = FinalString & "</Points></Series>"

CustomizedPane.CodeObject.GraphData = FinalString & "</CodejockChart>"

set xmlDoc = nothing

End Function