# Customized Panes for 'xxxxxxxx' Created: 2009/04/09
# PANE:Job Narrations
[PANE]
ADMIN INVPENLZ    01000Job Narrations                                                                                      020                                                                                                                                                                                                                                                               000000500000INVPEN000M
[VBSCRIPT]
' This script contains functions for customized pane events.
' You must not modify the name of the functions.
Option Explicit

Function CustomizedPane_OnLoad()
  ' Specify the variable used to contain the XML that defines the listview structure
  dim ListXML

  ' Populate the XML that defines the listview structure
  ListXML = ListXML & "<Columns PrimaryNode='NarrationItem' Style='DataGrid' AutoSize='false' >"
  ListXML = ListXML & "<Column Name='Line' Description='Line number' Type='numeric'  />"
  ListXML = ListXML & "<Column Name='Narration' Description='Narration' />"
  ListXML = ListXML & "</Columns>"

' Hidden='true'

  ' Take the XML and pass it to the ListviewProperties variable
  CustomizedPane.CodeObject.ListviewProperties = ListXML

End Function

Function CustomizedPane_OnRefresh()
  ' Specify the variables that will be used when calling the business object
  dim XMLOut, XMLParam, Job
  CustomizedPane.CodeObject.ListviewData = " "

  ' Populate the Stockcode variable with the refresh value
  Job = CustomizedPane.CodeObject.RefreshValue

  if Job = "" then
    exit function
  end if

  ' Build up the XML to be passed to the business object
  XMLParam = XMLParam & " <Query>"
  XMLParam = XMLParam & "   <Key>"
  XMLParam = XMLParam & "     <Job>" & Job & "</Job>"
  XMLParam = XMLParam & "   </Key>"
  XMLParam = XMLParam & "   <Option>"
  XMLParam = XMLParam & "   <IncludeJobNarrations>Y</IncludeJobNarrations>"
  XMLParam = XMLParam & "   </Option>"
  XMLParam = XMLParam & " </Query>"
  on error resume next


  ' Call the business object, supply the XML and put the resulting XML in to XMLOut
  XMLOut = CallBO("WIPQRY",XMLParam,"auto")
  if err then
    exit function
  end if
  ' Switch on error handling
  on error goto 0


  ' Define the variables required for building the new XML structure and extracting the information from
  ' the DOM. This is required because only lines containing the Narration information need to be restructured
  ' so that they can be displayed in a listview.
 
  Dim NewXML, NewXMLE, xDoc, xList, xList2, Counter, Counter2, NIB, NIE, LineB, LineE, NarB, NarE
  Dim XMLDoc, UseIncase, LineNumber

  NewXML = "<OutputXML>"
  NewXMLE = "</OutputXML>"
  NIB = "<NarrationItem>"
  NIE = "</NarrationItem>"
  LineB = "<Line>"
  LineE = "</Line>"
  NarB = "<Narration>"
  NarE = "</Narration>"


  ' Load the output from the business object in to the DOM
  Set XMLDoc = createobject("MSXML2.DOMDocument")
  XMLDoc.async = false
  XMLDoc.LoadXML(XMLOut)


    ' Locate the OperationItem elements
    Set xList2 = XMLDoc.SelectNodes("//WipQuery/JobHeader/HeaderNarration/Narration")

    ' Loop through each Narration section
    For Counter2 = 0 To xList2.length - 1
    
      LineNumber = Counter2 + 1

      ' Build the new XML containing the original content of the Narration nodes and
      ' combine the two required times and the two issued times.
      NewXML = NewXML & NIB
      NewXML = NewXML & LineB & LineNumber & LineE
      NewXML = NewXML & NarB & xList2(Counter2).SelectSingleNode(".").Text & NarE
      NewXML = NewXML & NIE
  
    Next

  ' Complete the XML by closing off the root element
  NewXML = NewXML & NewXMLE

  ' Load the new XML file in to the ListviewData variable
  CustomizedPane.CodeObject.ListviewData = NewXML

End Function