# Customized Panes for 'xxxxxxxx' Created: 2016/09/30
# PANE:Reserved Stock
[PANE]
ADMIN INVPENLZ    01000Reserved Stock                                                                                      020                                                                                                                                                                                                                                                               000000500000INVPEN000M
[VBSCRIPT]
' This script contains functions for customized pane events.
' You must not modify the name of the functions.
Option Explicit

Function CustomizedPane_OnLoad()
  ' Build up structure of listview using XML
  ' Define the column types to force the correct display of all fields
  ' Hide columns that are less likely to be used to reduce size
  dim ListXML

  ListXML = ListXML & "<Columns PrimaryNode='RSItem' Style='DataGrid' AutoSize='true' FreezeColumn='0' >"
  ListXML = ListXML & "<Column Name='SalesOrder' Description='Sales order' />"
  ListXML = ListXML & "<Column Name='SalesOrderLine' Description='Sales order line' />"
  ListXML = ListXML & "<Column Name='SCT' Description='Supply chain transfer' />"
  ListXML = ListXML & "<Column Name='OrderStatus' Description='Order status' />"
  ListXML = ListXML & "<Column Name='Customer' Description='Customer' />"
  ListXML = ListXML & "<Column Name='CustRequestDate' Description='Cust req/req ship date' Type='date' />"
  ListXML = ListXML & "<Column Name='Warehouse' Description='Warehouse' />"
  ListXML = ListXML & "<Column Name='OrderQty' Description='Order quantity' Type='numeric' Decimals='3' Alignment='right' />"
  ListXML = ListXML & "<Column Name='ShipQty' Description='Ship quantity' Type='numeric' Decimals='3' Alignment='right' />"
  ListXML = ListXML & "<Column Name='BackOrderQty' Description='Back order quantity' Type='numeric' Decimals='3' Alignment='right' Hidden='true' />"
  ListXML = ListXML & "<Column Name='OrderUom' Description='Order uom' Hidden = 'true' />"
  ListXML = ListXML & "<Column Name='QtyReserved' Description='Quantity reserved' Type='numeric' Decimals='3' Alignment='right' />"
  ListXML = ListXML & "<Column Name='StockQtyToShip' Description='Stock quantity to shp' Type='numeric' Decimals='3' Alignment='right' hidden='true' />"
  ListXML = ListXML & "<Column Name='QtyReservedShip' Description='Quantity reserved to ship' Type='numeric' Decimals='3' Alignment='right' />"
  ListXML = ListXML & "</Columns>"
  CustomizedPane.CodeObject.ListviewProperties = ListXML
End Function

Function CustomizedPane_OnRefresh()

  ' Define the variables required for building the XML and calling the business object
  dim XMLOut, XMLParam, StockCode
  CustomizedPane.CodeObject.ListviewData = " "

  ' Populate the Stockcode variable with the refresh value
  StockCode = CustomizedPane.CodeObject.RefreshValue

  if StockCode = "" then
    exit function
  end if

  ' Build up XML to call INVQWR business object. Set all options except sales orders to be N to reduce the
  ' amount of XML to be returned.

  XMLParam = XMLParam & " <Query>"
  XMLParam = XMLParam & "   <Key>"
  XMLParam = XMLParam & "     <StockCode><![CDATA[" & StockCode & "]]></StockCode>"
  XMLParam = XMLParam & "   </Key>"
  XMLParam = XMLParam & "   <Option>"
  XMLParam = XMLParam & "     <IncludeLots>N</IncludeLots>"
  XMLParam = XMLParam & "     <IncludeMultipleBins>N</IncludeMultipleBins>"
  XMLParam = XMLParam & "     <IncludeFIFOBuckets>N</IncludeFIFOBuckets>"
  XMLParam = XMLParam & "     <IncludeGoodsInInspection>N</IncludeGoodsInInspection>"
  XMLParam = XMLParam & "     <IncludeGoodsInTransit>N</IncludeGoodsInTransit>"
  XMLParam = XMLParam & "     <IncludeSupplyChainTransfers>Y</IncludeSupplyChainTransfers>"
  XMLParam = XMLParam & "     <IncludeSerialTracking>N</IncludeSerialTracking>"
  XMLParam = XMLParam & "     <IncludeAlternateStk>N</IncludeAlternateStk>"
  XMLParam = XMLParam & "     <IncludeAlternateSupplier>N</IncludeAlternateSupplier>"
  XMLParam = XMLParam & "     <IncludeECCRevisionRelease>N</IncludeECCRevisionRelease>"
  XMLParam = XMLParam & "     <IncludeLctRoutes>N</IncludeLctRoutes>"
  XMLParam = XMLParam & "     <IncludePurchaseOrders>N</IncludePurchaseOrders>"
  XMLParam = XMLParam & "     <IncludeBlanketPOrders>N</IncludeBlanketPOrders>"
  XMLParam = XMLParam & "     <IncludeForeignPrices>N</IncludeForeignPrices>"
  XMLParam = XMLParam & "     <IncludeBomWhereUsed>N</IncludeBomWhereUsed>"
  XMLParam = XMLParam & "     <IncludeWorkInProgress>N</IncludeWorkInProgress>"
  XMLParam = XMLParam & "     <IncludeWipAllocations>N</IncludeWipAllocations>"
  XMLParam = XMLParam & "     <IncludeJobsCompleted>E</IncludeJobsCompleted>"
  XMLParam = XMLParam & "     <IncludeSubJobs>N</IncludeSubJobs>"
  XMLParam = XMLParam & "     <IncludeBomRoutings>N</IncludeBomRoutings>"
  XMLParam = XMLParam & "     <IncludeBuildSchedule>N</IncludeBuildSchedule>"
  XMLParam = XMLParam & "     <IncludeBomStructures>N</IncludeBomStructures>"
  XMLParam = XMLParam & "     <IncludeSalesOrders>Y</IncludeSalesOrders>"
  XMLParam = XMLParam & "     <IncludeDispatchNotes>N</IncludeDispatchNotes>"
  XMLParam = XMLParam & "     <IncludePricing>N</IncludePricing>"
  XMLParam = XMLParam & "     <IncludeSupplierStockCode>N</IncludeSupplierStockCode>"
  XMLParam = XMLParam & "     <IncludeCustomerStockCode>N</IncludeCustomerStockCode>"
  XMLParam = XMLParam & "     <IncludeRequisitions>N</IncludeRequisitions>"
  XMLParam = XMLParam & "     <IncludeSalesHistory>N</IncludeSalesHistory>"
  XMLParam = XMLParam & "   </Option>"
  XMLParam = XMLParam & " </Query>"

  ' Call INVQWR business object using the above XML
  on error resume next
  XMLOut = CallBO("INVQWR",XMLParam,"auto")
  
  if err then
       exit function
  end if
  ' Switch on error handling
  on error goto 0

  ' Because the display should only contain lines where either the QtyReserved or QtyReservedShip contain
  ' a value you cannot just take the output from the business object. The following section is used to
  ' extract the values, check that the line contains values that are greater than zero, and build a new XML
  ' string that only contains these lines.

  ' Define the variables required for building the new XML structure and extracting the information from the DOM.
  Dim NewXML, NewXMLE, xDoc, xList, xList2, Counter, Counter2, XMLDoc
  Dim RSIB, RSIE, SOB, SOE, SOLB, SOLE, OSB, OSE, CB, CE, CRDB, CRDE,WB, WE, OQB, OQE, SQB, SQE, SCTB, SCTE
  Dim BOQB, BOQE, OUB, OUE, QRB, QRE, SQSB, SQSE, QRSB, QRSE

  ' Populate the variables with the element names. Ones ending in B are the beginning elements, ones ending in E are
  ' the ending elements
  NewXML = "<OutputXML>"
  NewXMLE = "</OutputXML>"
  RSIB = "<RSItem>"
  RSIE = "</RSItem>"
  SOB = "<SalesOrder>"
  SOE = "</SalesOrder>"
  SOLB = "<SalesOrderLine>"
  SOLE = "</SalesOrderLine>"
  OSB = "<OrderStatus>"
  OSE = "</OrderStatus>"
  CB = "<Customer>"
  CE = "</Customer>"
  CRDB = "<CustRequestDate>"
  CRDE = "</CustRequestDate>"
  WB = "<Warehouse>"
  WE = "</Warehouse>"
  OQB = "<OrderQty>"
  OQE = "</OrderQty>"
  SQB = "<ShipQty>"
  SQE = "</ShipQty>"
  BOQB = "<BackOrderQty>"
  BOQE = "</BackOrderQty>"
  OUB = "<OrderUom>"
  OUE = "</OrderUom>"
  QRB = "<QtyReserved>"
  QRE = "</QtyReserved>"
  SQSB = "<StockQtyToShip>"
  SQSE = "</StockQtyToShip>"
  QRSB = "<QtyReservedShip>"
  QRSE = "</QtyReservedShip>"
  SCTB = "<SCT>"
  SCTE = "</SCT>"


  ' Load the output from the business object in to the DOM
  Set XMLDoc = createobject("MSXML2.DOMDocument")
  XMLDoc.async = false
  XMLDoc.LoadXML(XMLOut)

  ' Look for all SalesOrderItem elements
  Set xList = XMLDoc.SelectNodes("//SalesOrderItem")

  ' Loop through each of the SalesOrderItem elements
  For Counter = 0 To xList.length - 1

    ' Check to see if either the QtyReserved or QtyReservedShip values are greater than zero
    If xList(Counter).SelectSingleNode("QtyReserved").Text > 0 OR xList(Counter).SelectSingleNode("QtyReservedShip").Text > 0 then
      ' Build the new XML containing the original content of the SSalesOrderItem nodes for those that have reserved stock
      NewXML = NewXML & RSIB
      NewXML = NewXML & SOB & xList(Counter).SelectSingleNode("SalesOrder").Text & SOE
      NewXML = NewXML & SOLB & xList(Counter).SelectSingleNode("SalesOrderLine").Text & SOLE
      NewXML = NewXML & OSB & xList(Counter).SelectSingleNode("OrderStatus").Text & OSE
      NewXML = NewXML & CB & xList(Counter).SelectSingleNode("Customer").Text & CE
      NewXML = NewXML & CRDB & xList(Counter).SelectSingleNode("MCustRequestDat").Text & CRDE
      NewXML = NewXML & WB & xList(Counter).SelectSingleNode("MWarehouse").Text & WE
      NewXML = NewXML & OQB & xList(Counter).SelectSingleNode("MOrderQty").Text & OQE
      NewXML = NewXML & SQB & xList(Counter).SelectSingleNode("MShipQty").Text & SQE
      NewXML = NewXML & BOQB & xList(Counter).SelectSingleNode("MBackOrderQty").Text & BOQE
      NewXML = NewXML & OUB & xList(Counter).SelectSingleNode("MOrderUom").Text & OUE
      NewXML = NewXML & QRB & xList(Counter).SelectSingleNode("QtyReserved").Text & QRE
      NewXML = NewXML & SQSB & xList(Counter).SelectSingleNode("MStockQtyToShp").Text & SQSE
      NewXML = NewXML & QRSB & xList(Counter).SelectSingleNode("QtyReservedShip").Text & QRSE
      NewXML = NewXML & RSIE
    End If

  Next

  ' Look for all SctItem elements
  Set xList2 = XMLDoc.SelectNodes("//SctItem")

  ' Loop through each of the SalesOrderItem elements
  For Counter2 = 0 To xList2.length - 1

    ' Check to see if either the QtyReserved or QtyReservedShip values are greater than zero
    If xList2(Counter2).SelectSingleNode("QtyReserved").Text > 0 OR xList2(Counter2).SelectSingleNode("QtyReservedShip").Text > 0 then
      ' Build the new XML containing the original content of the SSalesOrderItem nodes for those that have reserved stock
      NewXML = NewXML & RSIB
      NewXML = NewXML & SOB & xList2(Counter2).SelectSingleNode("SalesOrder").Text & SOE
      NewXML = NewXML & SOLB & xList2(Counter2).SelectSingleNode("SalesOrderLine").Text & SOLE
      NewXML = NewXML & OSB & xList2(Counter2).SelectSingleNode("OrderStatus").Text & OSE
      NewXML = NewXML & SCTB & "Yes" & SCTE
      NewXML = NewXML & CRDB & xList2(Counter2).SelectSingleNode("ReqShipDate").Text & CRDE
      NewXML = NewXML & WB & xList2(Counter2).SelectSingleNode("MWarehouse").Text & WE
      NewXML = NewXML & OQB & xList2(Counter2).SelectSingleNode("MOrderQty").Text & OQE
      NewXML = NewXML & SQB & xList2(Counter2).SelectSingleNode("MShipQty").Text & SQE
      NewXML = NewXML & BOQB & xList2(Counter2).SelectSingleNode("MBackOrderQty").Text & BOQE
      NewXML = NewXML & OUB & xList2(Counter2).SelectSingleNode("MOrderUom").Text & OUE
      NewXML = NewXML & QRB & xList2(Counter2).SelectSingleNode("QtyReserved").Text & QRE
      NewXML = NewXML & QRSB & xList2(Counter2).SelectSingleNode("QtyReservedShip").Text & QRSE
      NewXML = NewXML & RSIE
    End If

  Next

  ' Complete the XML by closing off the root element
  NewXML = NewXML & NewXMLE

  ' Load the new XML file in to the ListviewData variable
  CustomizedPane.CodeObject.ListviewData = NewXML

  ' Destroy the occurence of the DOM
  Set XMLDoc = Nothing

End Function